From 894aa5d5998092780495f68ff9de27d18692fbad Mon Sep 17 00:00:00 2001
From: roxblnfk <roxblnfk@ya.ru>
Date: Sun, 5 Jul 2026 14:53:42 +0400
Subject: [PATCH] Inject regex and printf format strings into PHP calls

Highlight embedded mini-languages inside PHP string arguments via tree-sitter
injections:
- the pattern argument of `preg_*` calls as a regular expression;
- the format string of `printf`/`sprintf`/`vprintf`/`vsprintf` (first argument)
  and `fprintf`/`vfprintf`/`sscanf`/`fscanf` (second argument) as printf.

Heredoc/nowdoc bodies already inject by tag: Zed resolves the tag against
language names and file extensions case-insensitively, so `<<<SQL`, `<<<HTML`,
`<<<JSON`, `<<<JS`, ... already work without per-language rules.
---
 languages/php/injections.scm | 42 ++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

diff --git a/languages/php/injections.scm b/languages/php/injections.scm
index c5f63f7..379cb6e 100644
--- a/languages/php/injections.scm
+++ b/languages/php/injections.scm
@@ -9,6 +9,48 @@
 ((comment) @injection.content
  (#set! injection.language "comment"))
 
+; Inject the heredoc/nowdoc body as the language named by its tag. Zed resolves
+; the tag against language names and file extensions, case-insensitively, so
+; `<<<SQL`, `<<<HTML`, `<<<JSON`, `<<<JS`, `<<<YML`, `<<<MD`, ... all work.
 ((heredoc_body) (heredoc_end) @injection.language) @injection.content
 
 ((nowdoc_body) (heredoc_end) @injection.language) @injection.content
+
+; Highlight the pattern argument of the PCRE functions as a regular expression.
+; Only functions whose first argument is a pattern (not `preg_quote`, whose
+; first argument is a literal string to escape).
+(function_call_expression
+  function: (name) @_preg
+  arguments: (arguments
+    .
+    (argument
+      [(string (string_content) @injection.content)
+       (encapsed_string (string_content) @injection.content)]))
+  (#any-of? @_preg
+    "preg_match" "preg_match_all" "preg_replace" "preg_replace_callback"
+    "preg_split" "preg_grep")
+  (#set! injection.language "regex"))
+
+; Highlight printf-style format strings (format is the first argument).
+(function_call_expression
+  function: (name) @_fmt
+  arguments: (arguments
+    .
+    (argument
+      [(string (string_content) @injection.content)
+       (encapsed_string (string_content) @injection.content)]))
+  (#any-of? @_fmt "sprintf" "printf" "vsprintf" "vprintf")
+  (#set! injection.language "printf"))
+
+; ... and where the format is the second argument.
+(function_call_expression
+  function: (name) @_fmt
+  arguments: (arguments
+    .
+    (argument)
+    .
+    (argument
+      [(string (string_content) @injection.content)
+       (encapsed_string (string_content) @injection.content)]))
+  (#any-of? @_fmt "fprintf" "vfprintf" "sscanf" "fscanf")
+  (#set! injection.language "printf"))